blob: 47b2133368b3e0785f4e05591d287c4870175f38 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
/*
test for example like this
$ hydra-eval-jobs pkgs/top-level/release-python.nix
*/
{
# The platforms for which we build Nixpkgs.
supportedSystems ? [
"aarch64-linux"
"x86_64-linux"
],
# Attributes passed to nixpkgs. Don't build packages marked as unfree.
nixpkgsArgs ? {
config = {
allowAliases = false;
allowUnfree = false;
inHydra = true;
};
__allowFileset = false;
},
}:
let
release-lib = import ./release-lib.nix {
inherit supportedSystems nixpkgsArgs;
};
inherit (release-lib) mapTestOn pkgs;
inherit (release-lib.lib) isDerivation mapAttrs optionals;
packagePython = mapAttrs (
name: value:
let
res = builtins.tryEval (
if isDerivation value then
value.meta.isBuildPythonPackage or [ ]
else if value.recurseForDerivations or false || value.recurseForRelease or false then
packagePython value
else
[ ]
);
in
optionals res.success res.value
);
jobs = {
# for pkgs.formats tests, which rely on remarshal
pkgs-lib-tests = import ../pkgs-lib/tests { inherit pkgs; };
tested = pkgs.releaseTools.aggregate {
name = "python-tested";
meta.description = "Release-critical packages from the python package sets";
constituents = [
jobs.nixos-render-docs.x86_64-linux # Used in nixos manual
jobs.remarshal_0_17.x86_64-linux # Used in pkgs.formats.yaml_1_1
jobs.python313Packages.afdko.x86_64-linux # Used in noto-fonts-color-emoji
jobs.python313Packages.buildcatrust.x86_64-linux # Used in pkgs.cacert
jobs.python313Packages.colorama.x86_64-linux # Used in nixos test-driver
jobs.python313Packages.ptpython.x86_64-linux # Used in nixos test-driver
jobs.python313Packages.requests.x86_64-linux # Almost ubiquous package
jobs.python313Packages.sphinx.x86_64-linux # Document creation for many packages
];
};
}
// (mapTestOn (packagePython pkgs));
in
jobs
|
