blob: 15000ef02c33a0580198ffa7f24b7c1569fb1326 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
{
bison,
fetchFromGitHub,
flex,
lib,
perl,
postgresql,
postgresqlBuildExtension,
stdenv,
}:
let
hashes = {
"18" = "sha256-Hqjg62YLTLEa6wRA5S4MAIED7Hobtiih4E55cSzVTqE";
"17" = "sha256-hAjhNj/benwZbbuxDl9RSjwWRai9CUozbEN6ecPKoFE=";
"16" = "sha256-iukdi2c3CukGvjuTojybFFAZBlAw8GEfzFPr2qJuwTA=";
"15" = "sha256-webZWgWZGnSoXwTpk816tjbtHV1UIlXkogpBDAEL4gM=";
"14" = "sha256-jZXhcYBubpjIJ8M5JHXKV5f6VK/2BkypH3P7nLxZz3E=";
"13" = "sha256-HR6nnWt/V2a0rD5eHHUsFIZ1y7lmvLz36URt9pPJnCw=";
};
in
postgresqlBuildExtension (finalAttrs: {
pname = "age";
version =
if lib.versionAtLeast postgresql.version "17" then
"1.7.0-rc0"
else if lib.versionAtLeast postgresql.version "16" then
"1.6.0-rc0"
else
"1.5.0-rc0";
src = fetchFromGitHub {
owner = "apache";
repo = "age";
tag = "PG${lib.versions.major postgresql.version}/v${finalAttrs.version}";
hash =
hashes.${lib.versions.major postgresql.version}
or (throw "Source for Age is not available for ${postgresql.version}");
};
makeFlags = [
"BISON=${bison}/bin/bison"
"FLEX=${flex}/bin/flex"
"PERL=${perl}/bin/perl"
];
enableUpdateScript = false;
passthru.tests = stdenv.mkDerivation {
inherit (finalAttrs) version src;
pname = "age-regression";
dontConfigure = true;
buildPhase =
let
postgresqlAge = postgresql.withPackages (_: [ finalAttrs.finalPackage ]);
in
''
# The regression tests need to be run in the order specified in the Makefile.
echo -e "include Makefile\nfiles:\n\t@echo \$(REGRESS)" > Makefile.regress
REGRESS_TESTS=$(make -f Makefile.regress files)
${lib.getDev postgresql}/lib/pgxs/src/test/regress/pg_regress \
--inputdir=./ \
--bindir='${postgresqlAge}/bin' \
--encoding=UTF-8 \
--load-extension=age \
--inputdir=./regress --outputdir=./regress --temp-instance=./regress/instance \
--port=61958 --dbname=contrib_regression \
$REGRESS_TESTS
'';
installPhase = ''
touch $out
'';
};
meta = {
broken = !builtins.elem (lib.versions.major postgresql.version) (builtins.attrNames hashes);
description = "Graph database extension for PostgreSQL";
homepage = "https://age.apache.org/";
changelog = "https://github.com/apache/age/raw/PG${lib.versions.major postgresql.version}/v${finalAttrs.version}/RELEASE";
maintainers = [ ];
platforms = postgresql.meta.platforms;
license = lib.licenses.asl20;
};
})
|
