blob: 1b16def315807fa7f55fe356ad97310e33b6b1f3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
{
lib,
buildPythonPackage,
fetchFromGitHub,
setuptools,
pg8000,
postgresql,
psycopg2,
pytestCheckHook,
pythonOlder,
sqlalchemy,
testing-common-database,
}:
buildPythonPackage rec {
pname = "testing-postgresql";
# Version 1.3.0 isn't working so let's use the latest commit from GitHub
version = "unstable-2017-10-31";
pyproject = true;
disabled = pythonOlder "3.7";
src = fetchFromGitHub {
owner = "tk0miya";
repo = "testing.postgresql";
rev = "c81ded434d00ec8424de0f9e1f4063c778c6aaa8";
hash = "sha256-A4tahAaa98X66ZYa3QxIQDZkwAwVB6ZDRObEhkbUWKs=";
};
build-system = [ setuptools ];
dependencies = [
testing-common-database
pg8000
];
nativeCheckInputs = [
pytestCheckHook
psycopg2
sqlalchemy
];
# Add PostgreSQL to search path
prePatch = ''
substituteInPlace src/testing/postgresql.py \
--replace-fail "/usr/local/pgsql" "${postgresql}"
'';
pythonRelaxDeps = [ "pg8000" ];
postPatch = ''
substituteInPlace setup.py \
--replace-fail "pg8000 >= 1.10" "pg8000"
substituteInPlace tests/test_postgresql.py \
--replace-fail "self.assertRegexpMatches" "self.assertRegex"
'';
pythonImportsCheck = [ "testing.postgresql" ];
# Fix tests for Darwin build. See:
# https://github.com/NixOS/nixpkgs/pull/74716#issuecomment-598546916
__darwinAllowLocalNetworking = true;
meta = with lib; {
description = "Use temporary postgresql instance in testing";
homepage = "https://github.com/tk0miya/testing.postgresql";
license = licenses.asl20;
platforms = platforms.linux;
maintainers = with maintainers; [ jluttine ];
};
}
|
