pkgs/development/python-modules/tensorrt/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

{
  autoPatchelfHook,
  buildPythonPackage,
  cudaPackages,
  lib,
  python,
  stdenv,
}:
let
  inherit (cudaPackages.tensorrt)
    meta
    pname
    src
    version
    ;
  inherit (lib.versions) major minor;
  inherit (stdenv.hostPlatform) parsed;
in
buildPythonPackage {
  # Make sure to add the cudaNamePrefix tag since we're not using cudaPackages.buildRedist but this is a
  # redistributable.
  pname = "${cudaPackages.cudaNamePrefix}-${pname}";

  inherit version;

  src =
    let
      # https://peps.python.org/pep-0427/#file-name-convention
      distribution = pname;
      pythonTag = "cp${major python.version}${minor python.version}";
      abiTag = "none";
      platformTag = "${parsed.kernel.name}_${parsed.cpu.name}";
    in
    src + "/python/${distribution}-${version}-${pythonTag}-${abiTag}-${platformTag}.whl";

  format = "wheel";

  nativeBuildInputs = [
    autoPatchelfHook
  ];

  buildInputs = [
    cudaPackages.tensorrt
  ];

  pythonImportsCheck = [ "tensorrt" ];

  meta = {
    description = "Python bindings for TensorRT, a high-performance deep learning interface";

    # Explicitly inherit from TensorRT's meta to avoid pulling in attributes added by stdenv.mkDerivation.
    inherit (meta)
      badPlatforms
      broken
      changelog
      downloadPage
      homepage
      license
      longDescription
      maintainers
      platforms
      sourceProvenance
      teams
      ;
  };
}