pkgs/development/python-modules/questionary/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

{
  stdenv,
  lib,
  buildPythonPackage,
  fetchFromGitHub,
  poetry-core,
  prompt-toolkit,
  pytestCheckHook,
}:

buildPythonPackage rec {
  pname = "questionary";
  version = "2.1.1";
  pyproject = true;

  src = fetchFromGitHub {
    owner = "tmbo";
    repo = "questionary";
    tag = version;
    hash = "sha256-r7F5y6KD6zonQGtO/9OuCTMTWdkCdd9aqTgKg6eWp08=";
  };

  pythonRelaxDeps = [ "prompt_toolkit" ];

  build-system = [ poetry-core ];

  dependencies = [ prompt-toolkit ];

  nativeCheckInputs = [ pytestCheckHook ];

  preCheck = lib.optionalString stdenv.hostPlatform.isDarwin ''
    ulimit -n 1024
  '';

  disabledTests = [
    # RuntimeError: no running event loop
    "test_blank_line_fix"

    # TypeError: Attrs.__new__() missing 1 required positional argument: 'dim'
    # https://github.com/tmbo/questionary/issues/461
    "test_print_with_style"
  ];

  pythonImportsCheck = [ "questionary" ];

  meta = {
    description = "Python library to build command line user prompts";
    homepage = "https://github.com/tmbo/questionary";
    changelog = "https://github.com/tmbo/questionary/blob/${src.rev}/docs/pages/changelog.rst";
    license = lib.licenses.mit;
    maintainers = with lib.maintainers; [ fab ];
  };
}