1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
|
{
lib,
buildPythonPackage,
fetchFromGitHub,
pythonOlder,
stdenvNoCC,
replaceVars,
buildNpmPackage,
python,
home-assistant-chip-wheels,
# build
setuptools,
# dependencies
aiohttp,
aiorun,
atomicwrites,
coloredlogs,
orjson,
home-assistant-chip-clusters,
# optionals
cryptography,
home-assistant-chip-core,
zeroconf,
# tests
aioresponses,
pytest,
pytest-aiohttp,
pytest-cov-stub,
pytestCheckHook,
# build options
withDashboard ? true,
}:
let
version = "8.1.2";
src = fetchFromGitHub {
owner = "home-assistant-libs";
repo = "python-matter-server";
tag = version;
hash = "sha256-vnI57h/aesnaDYorq1PzcMCLmV0z0ZBJvMg4Nzh1Dtc=";
};
paaCerts = stdenvNoCC.mkDerivation {
pname = "matter-server-paa-certificates";
inherit (home-assistant-chip-wheels) version src;
dontConfigure = true;
dontBuild = true;
installPhase = ''
runHook preInstall
mkdir -p $out
cp connectedhomeip/credentials/development/paa-root-certs/* $out/
runHook postInstall
'';
};
# Maintainer note: building the dashboard requires a python environment with a
# built version of python-matter-server. To support bundling the dashboard
# with the python-matter-server, the build is parameterized to build without
# a dependency on the dashboard, breaking a cyclical dependency. First,
# python-matter-server is built without the dashboard, then the dashboard is
# built, then python-matter-server is built again with the dashboard.
matterServerDashboard =
let
pythonWithChip = python.withPackages (ps: [
ps.home-assistant-chip-clusters
(ps.python-matter-server.override { withDashboard = false; })
]);
in
buildNpmPackage {
pname = "python-matter-server-dashboard";
inherit src version;
npmDepsHash = "sha256-IgI1H3VlTq66duplVQqL67SpgxPF2MOowDn+ICMXCik=";
prePatch = ''
${pythonWithChip.interpreter} scripts/generate_descriptions.py
# cd before the patch phase sets up the npm install hook to find the
# package.json. The script would need to be patched in order to be used
# with sourceRoot.
cd "dashboard"
'';
# This package does not contain a normal `npm build` step.
buildPhase = ''
env NODE_ENV=production npm exec -- tsc
env NODE_ENV=production npm exec -- rollup -c
'';
installPhase = ''
runHook preInstall
install -Dt "$out/" public/*
# Copy recursive directory structure, which install does not do.
cp -r dist/web/* "$out/"
runHook postInstall
'';
};
in
buildPythonPackage rec {
pname = if withDashboard then "python-matter-server" else "python-matter-server-without-dashboard";
inherit
src
version
;
pyproject = true;
disabled = pythonOlder "3.12";
patches = [
(replaceVars ./link-paa-root-certs.patch {
paacerts = paaCerts;
})
];
postPatch = ''
substituteInPlace pyproject.toml \
--replace-fail 'version = "0.0.0"' 'version = "${version}"'
''
+ lib.optionalString withDashboard ''
substituteInPlace "matter_server/server/server.py" \
--replace-fail 'Path(__file__).parent.joinpath("../dashboard/")' 'Path("${matterServerDashboard}")'
'';
build-system = [
setuptools
];
pythonRelaxDeps = [ "home-assistant-chip-clusters" ];
dependencies = [
aiohttp
aiorun
atomicwrites
coloredlogs
orjson
home-assistant-chip-clusters
];
optional-dependencies = {
server = [
cryptography
home-assistant-chip-core
zeroconf
];
};
nativeCheckInputs = [
aioresponses
pytest-aiohttp
pytest-cov-stub
pytestCheckHook
]
++ lib.concatAttrValues optional-dependencies;
preCheck =
let
pythonEnv = python.withPackages (_: dependencies ++ nativeCheckInputs ++ [ pytest ]);
in
''
export PYTHONPATH=${pythonEnv}/${python.sitePackages}
'';
disabledTestPaths = [
# requires internet access
"tests/server/ota/test_dcl.py"
];
meta = {
changelog = "https://github.com/home-assistant-libs/python-matter-server/releases/tag/${src.tag}";
description = "Python server to interact with Matter";
mainProgram = "matter-server";
homepage = "https://github.com/home-assistant-libs/python-matter-server";
license = lib.licenses.asl20;
teams = [ lib.teams.home-assistant ];
};
}
|
