1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
{
stdenv,
lib,
pkgsCross,
buildPythonPackage,
fetchFromGitHub,
gitUpdater,
setuptools-scm,
pdfium-binaries,
numpy,
pillow,
pytestCheckHook,
removeReferencesTo,
python,
}:
let
# They demand their own fork of ctypesgen
ctypesgen = buildPythonPackage rec {
pname = "ctypesgen";
version = "1.1.1+g${src.rev}"; # the most recent tag + git version
pyproject = true;
src = fetchFromGitHub {
owner = "pypdfium2-team";
repo = "ctypesgen";
rev = "3961621c3e057015362db82471e07f3a57822b15";
hash = "sha256-0OBY7/Zn12rG20jNYG65lANTRVRIFvE0SgUdYGFpRtU=";
};
build-system = [
setuptools-scm
];
};
in
buildPythonPackage rec {
pname = "pypdfium2";
version = "5.3.0";
pyproject = true;
src = fetchFromGitHub {
owner = "pypdfium2-team";
repo = "pypdfium2";
tag = version;
hash = "sha256-HXJv7GCb+r1rE9Jh0wHm/LCfr8eHJA7qtCk0YhbE+24=";
};
build-system = [
ctypesgen
setuptools-scm
];
nativeBuildInputs = [
removeReferencesTo
];
propagatedBuildInputs = [
pdfium-binaries
];
preBuild = ''
getVersion() {
cat ${pdfium-binaries}/VERSION | grep $1 | sed 's/.*=//'
}
export GIVEN_FULLVER="$(getVersion MAJOR).$(getVersion MINOR).$(getVersion BUILD).$(getVersion PATCH)"
'';
env = {
PDFIUM_PLATFORM = "system-search:${pdfium-binaries.version}";
PDFIUM_HEADERS = "${pdfium-binaries}/include";
PDFIUM_BINARY = "${pdfium-binaries}/lib/libpdfium${stdenv.targetPlatform.extensions.sharedLibrary}";
CPP = "${stdenv.cc.targetPrefix}cpp";
};
# Remove references to stdenv in comments.
postInstall = ''
remove-references-to -t ${stdenv.cc.cc} $out/${python.sitePackages}/pypdfium2_raw/bindings.py
'';
nativeCheckInputs = [
numpy
pillow
pytestCheckHook
];
pythonImportsCheck = [
"pypdfium2"
];
passthru = {
updateScript = gitUpdater {
allowedVersions = "^[.0-9]+$";
};
tests.cross = pkgsCross.aarch64-multiplatform.python3Packages.pypdfium2;
};
meta = {
changelog = "https://github.com/pypdfium2-team/pypdfium2/releases/tag/${version}";
description = "Python bindings to PDFium";
homepage = "https://pypdfium2.readthedocs.io/";
license = with lib.licenses; [
asl20 # or
mit
];
maintainers = with lib.maintainers; [ booxter ];
};
}
|
