blob: 16e959977440aa76a1320a7b2571a829a97ead03 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
{
buildPythonPackage,
fetchPypi,
lib,
python,
setuptools,
protobuf,
}:
buildPythonPackage rec {
pname = "protobuf";
version = "6.33.2";
pyproject = true;
src = fetchPypi {
inherit pname version;
hash = "sha256-Vtw3DJH7uKyFvBNYLJ43NWlmiikKouZqWQwqDTXdueQ=";
};
build-system = [ setuptools ];
propagatedNativeBuildInputs = [
protobuf
];
doCheck =
# https://protobuf.dev/support/cross-version-runtime-guarantee/#backwards
# The non-python protobuf provides the protoc binary which must not be newer.
assert lib.versionAtLeast version ("6." + protobuf.version);
# the pypi source archive does not ship tests
false;
pythonImportsCheck = [
"google.protobuf"
"google.protobuf.compiler"
"google.protobuf.internal"
"google.protobuf.pyext"
"google.protobuf.testdata"
"google.protobuf.util"
"google._upb._message"
];
# Tries to explicitly create a namespace package with pkg_resources,
# which breaks everything with our PYTHONPATH setup.
postInstall = ''
rm $out/${python.sitePackages}/google/__init__.py
'';
meta = {
description = "Protocol Buffers are Google's data interchange format";
homepage = "https://developers.google.com/protocol-buffers/";
changelog = "https://github.com/protocolbuffers/protobuf/releases/v${
builtins.substring 2 (-1) version
}";
license = lib.licenses.bsd3;
maintainers = with lib.maintainers; [ GaetanLepage ];
};
}
|
