1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
|
{
lib,
stdenv,
buildPythonPackage,
pytestCheckHook,
fetchFromGitHub,
fetchpatch,
replaceVars,
exiftool,
ffmpeg,
setuptools,
wrapGAppsHook3,
gdk-pixbuf,
gnome,
gobject-introspection,
librsvg,
poppler_gi,
webp-pixbuf-loader,
mutagen,
pygobject3,
pycairo,
dolphinIntegration ? false,
kdePackages,
versionCheckHook,
}:
buildPythonPackage rec {
pname = "mat2";
version = "0.14.0";
pyproject = true;
src = fetchFromGitHub {
owner = "jvoisin";
repo = "mat2";
tag = version;
hash = "sha256-JTt2/PuSxOXXHUuRP42y8jxw09mNMMz1piJM4ldnjq0=";
};
patches = [
# hardcode paths to some binaries
(replaceVars ./paths.patch {
exiftool = lib.getExe exiftool;
ffmpeg = lib.getExe ffmpeg;
kdialog = if dolphinIntegration then lib.getExe kdePackages.kdialog else null;
# replaced in postPatch
mat2 = null;
mat2svg = null;
})
# the executable shouldn't be called .mat2-wrapped
./executable-name.patch
# hardcode path to mat2 executable
./tests.patch
(fetchpatch {
name = "fix-test_html.patch";
url = "https://github.com/jvoisin/mat2/commit/00b4f110711754496932c59d5af3c0b2ed694484.patch";
hash = "sha256-5h/nM1dK8HmYtoIBVGOvUegMFBpGxcfpn5O6QrjLi9M=";
})
];
postPatch = ''
substituteInPlace dolphin/mat2.desktop \
--replace "@mat2@" "$out/bin/mat2" \
--replace "@mat2svg@" "$out/share/icons/hicolor/scalable/apps/mat2.svg"
'';
build-system = [ setuptools ];
nativeBuildInputs = [
gobject-introspection
wrapGAppsHook3
];
buildInputs = [
gdk-pixbuf
poppler_gi
];
dependencies = [
mutagen
pygobject3
pycairo
];
postInstall = ''
export GDK_PIXBUF_MODULE_FILE="${
gnome._gdkPixbufCacheBuilder_DO_NOT_USE {
extraLoaders = [
librsvg
webp-pixbuf-loader
];
}
}"
install -Dm 444 data/mat2.svg -t "$out/share/icons/hicolor/scalable/apps"
install -Dm 444 doc/mat2.1 -t "$out/share/man/man1"
''
+ lib.optionalString dolphinIntegration ''
install -Dm 444 dolphin/mat2.desktop -t "$out/share/kservices5/ServiceMenus"
'';
nativeCheckInputs = [ pytestCheckHook ];
nativeInstallCheckInputs = [ versionCheckHook ];
meta = {
description = "Handy tool to trash your metadata";
homepage = "https://github.com/jvoisin/mat2";
changelog = "https://github.com/jvoisin/mat2/blob/${src.tag}/CHANGELOG.md";
license = lib.licenses.lgpl3Plus;
mainProgram = "mat2";
maintainers = with lib.maintainers; [ dotlambda ];
};
}
|
