1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
|
{
lib,
aetcd,
buildPythonPackage,
coredis,
deprecated,
etcd3,
fetchFromGitHub,
flaky,
hiro,
importlib-resources,
motor,
packaging,
pymemcache,
pymongo,
pytest-asyncio,
pytest-benchmark,
pytest-cov-stub,
pytest-lazy-fixtures,
pytestCheckHook,
pythonOlder,
redis,
setuptools,
typing-extensions,
valkey,
}:
buildPythonPackage rec {
pname = "limits";
version = "5.4.0";
pyproject = true;
src = fetchFromGitHub {
owner = "alisaifee";
repo = "limits";
tag = version;
# Upstream uses versioneer, which relies on git attributes substitution.
# This leads to non-reproducible archives on github. Remove the substituted
# file here, and recreate it later based on our version info.
hash = "sha256-EHLqkd5Muazr52/oYaLklFVvF+AzJWGbFaaIG+T0ulE=";
postFetch = ''
rm "$out/limits/_version.py"
'';
};
patches = [
./only-test-in-memory.patch
];
postPatch = ''
substituteInPlace pytest.ini \
--replace-fail "-K" ""
substituteInPlace setup.py \
--replace-fail "versioneer.get_version()" "'${version}'"
# Recreate _version.py, deleted at fetch time due to non-reproducibility.
echo 'def get_versions(): return {"version": "${version}"}' > limits/_version.py
'';
build-system = [ setuptools ];
dependencies = [
deprecated
importlib-resources
packaging
typing-extensions
];
optional-dependencies = {
redis = [ redis ];
rediscluster = [ redis ];
memcached = [ pymemcache ];
mongodb = [ pymongo ];
etcd = [ etcd3 ];
async-redis = [ coredis ];
# async-memcached = [
# emcache # Missing module
# ];
async-mongodb = [ motor ];
async-etcd = [ aetcd ];
valkey = [ valkey ];
};
env = {
# make protobuf compatible with old versions
# https://developers.google.com/protocol-buffers/docs/news/2022-05-06#python-updates
PROTOCOL_BUFFERS_PYTHON_IMPLEMENTATION = "python";
};
nativeCheckInputs = [
flaky
hiro
pytest-asyncio
pytest-benchmark
pytest-cov-stub
pytest-lazy-fixtures
pytestCheckHook
]
++ lib.concatAttrValues optional-dependencies;
pytestFlags = [ "--benchmark-disable" ];
disabledTests = [
"test_moving_window_memcached"
# Flaky: compares time to magic value
"test_sliding_window_counter_previous_window"
];
pythonImportsCheck = [ "limits" ];
meta = {
description = "Rate limiting using various strategies and storage backends such as redis & memcached";
homepage = "https://github.com/alisaifee/limits";
changelog = "https://github.com/alisaifee/limits/releases/tag/${src.tag}";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ sarahec ];
};
}
|
