blob: c25332464f0781f1ddcb2d3fd638c9578d9e2f5f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
{
lib,
stdenv,
aiohttp,
audioop-lts,
buildPythonPackage,
fetchFromGitHub,
ffmpeg,
libopus,
pynacl,
setuptools,
withVoice ? true,
}:
let
pname = "discord.py";
version = "2.6.4";
in
buildPythonPackage {
inherit pname version;
pyproject = true;
src = fetchFromGitHub {
owner = "Rapptz";
repo = "discord.py";
tag = "v${version}";
hash = "sha256-glFXgTNdOQ3cG/jlvi/1ASon2HpcoKli45IhLhjpIvA=";
};
build-system = [ setuptools ];
dependencies = [
aiohttp
audioop-lts
]
++ lib.optionals withVoice [ pynacl ];
patchPhase = lib.optionalString withVoice ''
substituteInPlace "discord/opus.py" \
--replace-fail "ctypes.util.find_library('opus')" "'${libopus}/lib/libopus${stdenv.hostPlatform.extensions.sharedLibrary}'"
substituteInPlace "discord/player.py" \
--replace-fail "executable: str = 'ffmpeg'" "executable: str = '${lib.getExe ffmpeg}'"
'';
# Only have integration tests with discord
doCheck = false;
pythonImportsCheck = [
"discord"
"discord.types"
"discord.ui"
"discord.webhook"
"discord.app_commands"
"discord.ext.commands"
"discord.ext.tasks"
];
meta = {
description = "Python wrapper for the Discord API";
homepage = "https://discordpy.rtfd.org/";
changelog = "https://github.com/Rapptz/discord.py/blob/v${version}/docs/whats_new.rst";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ getpsyched ];
};
}
|
