blob: 1669bbd25334165f0840e55c20f11f805ea2d198 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
{
lib,
stdenv,
fetchurl,
unzip,
sqlite,
tcl,
}:
let
archiveVersion = import ./archive-version.nix lib;
mkTool =
{
pname,
makeTarget,
description,
homepage,
mainProgram,
}:
stdenv.mkDerivation rec {
inherit pname;
version = "3.51.1";
# nixpkgs-update: no auto update
src =
assert version == sqlite.version;
fetchurl {
url = "https://sqlite.org/2025/sqlite-src-${archiveVersion version}.zip";
hash = "sha256-D452WsjqfDbPjqm//dXBA1ZPSopjXyFfn3g7M4oT2XE=";
};
nativeBuildInputs = [ unzip ];
buildInputs = [ tcl ];
makeFlags = [ makeTarget ];
installPhase = "install -Dt $out/bin ${makeTarget}";
meta = {
inherit description homepage mainProgram;
downloadPage = "http://sqlite.org/download.html";
license = lib.licenses.publicDomain;
maintainers = with lib.maintainers; [ johnazoidberg ];
platforms = lib.platforms.unix;
};
};
in
{
sqldiff = mkTool {
pname = "sqldiff";
makeTarget = "sqldiff";
description = "Tool that displays the differences between SQLite databases";
homepage = "https://www.sqlite.org/sqldiff.html";
mainProgram = "sqldiff";
};
sqlite-analyzer = mkTool {
pname = "sqlite-analyzer";
makeTarget = "sqlite3_analyzer";
description = "Tool that shows statistics about SQLite databases";
homepage = "https://www.sqlite.org/sqlanalyze.html";
mainProgram = "sqlite3_analyzer";
};
sqlite-rsync = mkTool {
pname = "sqlite-rsync";
makeTarget = "sqlite3_rsync";
description = "Database remote-copy tool for SQLite";
homepage = "https://www.sqlite.org/rsync.html";
mainProgram = "sqlite3_rsync";
};
}
|
