blob: d0f1a66b440a4ce45f30a9ef405e829294eea83a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
{
stdenv,
lib,
fetchFromGitHub,
testers,
doxygen,
qmake,
qtbase,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "qdjango";
version = "unstable-2018-03-07";
src = fetchFromGitHub {
owner = "jlaine";
repo = "qdjango";
rev = "bda4755ece9d173a67b880e498027fcdc51598a8";
hash = "sha256-5MfRfsIlv73VMvKMBCLviXFovyGH0On5ukLIEy7zwkk=";
};
outputs = [
"out"
"dev"
"doc"
];
postPatch = ''
# HTML docs depend on regular docs
substituteInPlace qdjango.pro \
--replace 'dist.depends = docs' 'htmldocs.depends = docs'
''
+ lib.optionalString stdenv.hostPlatform.isDarwin ''
# tst_Auth:constIterator (tests/db/auth/tst_auth.cpp:624) fails on Darwin?
# QVERIFY(&*(it += 2) == 0) evals to false
substituteInPlace tests/db/db.pro \
--replace 'auth' ""
'';
qmakeFlags = [
# Uses Qt testing infrastructure via QMake CONFIG testcase,
# defaults to installing all testcase targets under Qt prefix
# https://github.com/qt/qtbase/blob/29400a683f96867133b28299c0d0bd6bcf40df35/mkspecs/features/testcase.prf#L110-L120
"CONFIG+=no_testcase_installs"
# Qmake-generated pkg-config files default to Qt prefix
"QMAKE_PKGCONFIG_PREFIX=${placeholder "out"}"
];
nativeBuildInputs = [
doxygen
qmake
];
dontWrapQtApps = true;
doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
preCheck = ''
export QT_PLUGIN_PATH=${lib.getBin qtbase}/${qtbase.qtPluginPrefix}
''
+ lib.optionalString stdenv.hostPlatform.isDarwin ''
# at this point in the build, install_name for dylibs hasn't been patched yet so we need to set the library path.
# for some reason, this doesn't work when just exporting the needed paths even though the autogenerated wrappers
# should at most prepend paths? just patch them into the wrappers instead
substituteInPlace $(find tests -name target_wrapper.sh) \
--replace 'DYLD_LIBRARY_PATH=' "DYLD_LIBRARY_PATH=$PWD/src/db:$PWD/src/http:"
'';
passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
meta = {
description = "Qt-based C++ web framework";
homepage = "https://github.com/jlaine/qdjango";
license = lib.licenses.lgpl21Plus;
maintainers = with lib.maintainers; [ OPNA2608 ];
platforms = lib.platforms.all;
pkgConfigModules = [
"qdjango-db"
"qdjango-http"
];
};
})
|
