1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
{
fetchFromGitHub,
git,
lib,
nodejs,
pnpm_10,
fetchPnpmDeps,
pnpmConfigHook,
stdenv,
nix-update-script,
discord,
discord-ptb,
discord-canary,
discord-development,
buildWebExtension ? false,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "equicord";
# Upstream discourages inferring the package version from the package.json found in
# the Equicord repository. Dates as tags (and automatic releases) were the compromise
# we came to with upstream. Please do not change the version schema (e.g., to semver)
# unless upstream changes the tag schema from dates.
version = "2026-01-19";
src = fetchFromGitHub {
owner = "Equicord";
repo = "Equicord";
tag = finalAttrs.version;
hash = "sha256-pEFU1E+BqAAAz2ywPrS1MejhZ/g47iG/4BBey+2F7Hw=";
};
pnpmDeps = fetchPnpmDeps {
inherit (finalAttrs) pname version src;
pnpm = pnpm_10;
fetcherVersion = 1;
hash = "sha256-iBCA4G1E1Yw/d94pQzcbBGJYeIIgZI+Gw87/x4ogoyg=";
};
nativeBuildInputs = [
git
nodejs
pnpmConfigHook
pnpm_10
];
env = {
EQUICORD_REMOTE = "${finalAttrs.src.owner}/${finalAttrs.src.repo}";
EQUICORD_HASH = "${finalAttrs.src.tag}";
};
buildPhase = ''
runHook preBuild
pnpm run ${if buildWebExtension then "buildWeb" else "build"} \
-- --standalone --disable-updater
runHook postBuild
'';
installPhase = ''
runHook preInstall
cp -r dist/${lib.optionalString buildWebExtension "chromium-unpacked/"} $out
runHook postInstall
'';
passthru = {
updateScript = nix-update-script {
extraArgs = [
"--version-regex"
"^(\\d{4}-\\d{2}-\\d{2})$"
];
};
tests = lib.genAttrs' [ discord discord-ptb discord-canary discord-development ] (
p: lib.nameValuePair p.pname p.tests.withEquicord
);
};
meta = {
description = "Other cutest Discord client mod";
homepage = "https://github.com/Equicord/Equicord";
license = lib.licenses.gpl3Only;
platforms = lib.platforms.unix;
maintainers = [
lib.maintainers.NotAShelf
];
};
})
|
