pythonPackages.ipython: 5.3.0 -> 6.0.0

1 files changed, 71 insertions, 0 deletions

diff --git a/pkgs/development/python-modules/ipython/default.nix b/pkgs/development/python-modules/ipython/default.nix
new file mode 100644
index 000000000000..0823a76e2a69
--- /dev/null
+++ b/pkgs/development/python-modules/ipython/default.nix
@@ -0,0 +1,71 @@
+{ lib
+, stdenv
+, buildPythonPackage
+, fetchPypi
+, pythonOlder
+# Build dependencies
+, glibcLocales
+# Test dependencies
+, nose
+, pygments
+, isPy27
+, mock
+# Runtime dependencies
+, jedi
+, decorator
+, pickleshare
+, simplegeneric
+, traitlets
+, prompt_toolkit
+, pexpect
+, appnope
+}:
+
+buildPythonPackage rec {
+  pname = "ipython";
+  version = "6.0.0";
+  name = "${pname}-${version}";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "f429b82b8d9807068da734b15965768bd21b15d0b706340b6d1b4d6f6f5b98a4";
+  };
+
+  prePatch = lib.optionalString stdenv.isDarwin ''
+    substituteInPlace setup.py --replace "'gnureadline'" " "
+  '';
+
+  buildInputs = [ glibcLocales ];
+
+  checkInputs = [ nose pygments ] ++ lib.optional isPy27 mock;
+
+  propagatedBuildInputs = [
+    jedi
+    decorator
+    pickleshare
+    simplegeneric
+    traitlets
+    prompt_toolkit
+    pexpect
+  ] ++ lib.optionals stdenv.isDarwin [appnope];
+
+  LC_ALL="en_US.UTF-8";
+
+  doCheck = false; # Circular dependency with ipykernel
+
+  checkPhase = ''
+    nosetests
+  '';
+
+  # IPython 6.0.0 and above does not support Python < 3.3.
+  # The last IPython version to support older Python versions
+  # is 5.3.x.
+  disabled = pythonOlder "3.3";
+
+  meta = {
+    description = "IPython: Productive Interactive Computing";
+    homepage = http://ipython.org/;
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ bjornfor jgeerds fridh ];
+  };
+}