blob: 73af231b7e48f1fc736066c73375f6263e1259a6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
{
lib,
stdenv,
fetchFromGitLab,
getopt,
lua,
boost,
libxcrypt,
pkg-config,
swig,
perl,
gcc,
}:
let
self = stdenv.mkDerivation rec {
pname = "highlight";
version = "4.19";
src = fetchFromGitLab {
owner = "saalen";
repo = "highlight";
rev = "v${version}";
hash = "sha256-4sPjTLgC4W77alpE/uZHOrnWKVXrWxeCtK70A6G87s8=";
};
enableParallelBuilding = true;
nativeBuildInputs = [
pkg-config
swig
perl
]
++ lib.optional stdenv.hostPlatform.isDarwin gcc;
buildInputs = [
getopt
lua
boost
libxcrypt
];
postPatch = ''
substituteInPlace src/makefile \
--replace "shell pkg-config" "shell $PKG_CONFIG"
substituteInPlace makefile \
--replace 'gzip' 'gzip -n'
''
+ lib.optionalString stdenv.cc.isClang ''
substituteInPlace src/makefile \
--replace 'CXX=g++' 'CXX=clang++'
'';
preConfigure = ''
makeFlags="PREFIX=$out conf_dir=$out/etc/highlight/ CXX=$CXX AR=$AR"
'';
# This has to happen _before_ the main build because it does a
# `make clean' for some reason.
preBuild = lib.optionalString (!stdenv.hostPlatform.isDarwin) ''
make -C extras/swig $makeFlags perl
'';
postCheck = lib.optionalString (!stdenv.hostPlatform.isDarwin) ''
perl -Iextras/swig extras/swig/testmod.pl
'';
preInstall = lib.optionalString (!stdenv.hostPlatform.isDarwin) ''
mkdir -p $out/${perl.libPrefix}
install -m644 extras/swig/highlight.{so,pm} $out/${perl.libPrefix}
make -C extras/swig clean # Clean up intermediate files.
'';
meta = {
description = "Source code highlighting tool";
mainProgram = "highlight";
homepage = "http://www.andre-simon.de/doku/highlight/en/highlight.php";
platforms = lib.platforms.unix;
maintainers = [ ];
};
};
in
if stdenv.hostPlatform.isDarwin then self else perl.pkgs.toPerlModule self
|
