pkgs/os-specific/linux/ithc/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

{
  lib,
  stdenv,
  fetchFromGitHub,
  kernel,
  kernelModuleMakeFlags,
}:

stdenv.mkDerivation rec {
  pname = "ithc";
  version = "unstable-2022-06-07";

  src = fetchFromGitHub {
    owner = "quo";
    repo = "ithc-linux";
    rev = "5af2a2213d2f3d944b19ec7ccdb96f16d56adddb";
    hash = "sha256-p4TooWUOWPfNdePE18ESmRJezPDAl9nLb55LQtkJiSg=";
  };

  nativeBuildInputs = kernel.moduleBuildDependencies;

  makeFlags = kernelModuleMakeFlags ++ [
    "VERSION=${version}"
    "KDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
  ];

  postPatch = ''
    sed -i ./Makefile -e '/depmod/d'
  '';

  installFlags = [ "INSTALL_MOD_PATH=${placeholder "out"}" ];

  meta = {
    description = "Linux driver for Intel Touch Host Controller";
    homepage = "https://github.com/quo/ithc-linux";
    license = lib.licenses.publicDomain;
    maintainers = with lib.maintainers; [ aacebedo ];
    platforms = lib.platforms.linux;
    broken = kernel.kernelOlder "5.9" || kernel.kernelAtLeast "6.10";
  };
}